home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
C64
/
F-French
/
(c)f1.d64
/
tombe
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2007-02-04
|
3KB
|
71 lines
0 POKE56,28:CLR:PRINT"[147]":POKE53280,2:POKE53281,0:GOTO3000:PH=0:SC=0
1 GOSUB2000:C=55296:DX=1:DY=1:EX(1)=5:EX(2)=20:EX(3)=35
2 Q=40:EY(1)=12:EY(2)=6:EY(3)=22:POKE1982,32
3 POKE1024+Q*DY+DX,33:POKEC+Q*DY+DX,4
4 FORZ=1TO3:POKE1024+Q*EY(Z)+EX(Z),36:POKEC+Q*EY(Z)+EX(Z),5:NEXT
5 POKE2023,37:POKE56295,7:S=1024
6 CL=54272:VL=CL+24:FORI=CLTOCL+24:POKEI,0:NEXT
11 TR=500
18 POKEVL,15:POKECL+5,15:POKECL+6,129:FORZ=1TO25:NEXT:POKEVL,0
20 X1=PEEK(56320):CY=-(((X1AND1)=1)+((X1AND2)=2)*-1)
21 CX=((X1AND8)=8)+((X1AND4)=4)*-1
23 IFCX=0ANDCY=0THEN80
24 IF PEEK(S+Q*(DY+CY)+(DX+CX))=35THEN80
25 POKES+Q*DY+DX,32:DX=DX+CX:DY=DY+CY:IFPEEK(S+Q*DY+DX)=36THEN4000
28 POKEC+Q*DY+DX,4:POKES+Q*DY+DX,33
29 IFS+Q*DY+DX=2023THEN5000
80 B=INT(RND(1)*3)+1:CX(B)=0:CY(B)=0:W=0
81 POKES+Q*EY(B)+EX(B),32:CX(B)=((EX(B)>DX)-(EX(B)<DX))
82 EX(B)=EX(B)+CX(B)
85 CY(B)=((EY(B)>DY)-(EY(B)<DY))
86 IF PEEK(S+Q*EY(B)+EX(B)+Q*CY(B))=35THENCY(B)=0:EX(B)=EX(B)-CX(B)
87 EY(B)=EY(B)+CY(B)
88 IFPEEK(S+Q*EY(B)+EX(B))=33THEN4000
89 POKES+Q*EY(B)+EX(B),36:POKEC+Q*EY(B)+EX(B),5:TR=TR-1:GOTO18
91 GOTO18
299 CX(B)=0:CY(B)=0
1999 END
2000 FORM=1064TO1983
2001 IFINT(RND(1)*3)=1ANDPEEK(M-1)<>35THEN2004
2002 NEXT
2003 RETURN
2004 POKEM+54272,2:POKEM,35:NEXT
2999 RETURN
3000 POKE56334,PEEK(56334)AND254:POKE1,PEEK(1)AND251:PRINT" ";
3001 PRINT" ATTENDEZ[146]":FORI=0TO511:POKEI+12288,PEEK(I+53248):NEXTI
3002 FORI=12552TO12559:READJ:POKEI,J:NEXT
3003 DATA60,60,24,255,60,60,102,102
3004 FORI=12568TO12575:READJ:POKEI,J:NEXT
3005 DATA255,255,255,255,255,255,255,255
3006 FORI=12576TO12583:READJ:POKEI,J:NEXT
3007 DATA129,153,102,60,255,60,66,66
3008 FORI=12584TO12591:READJ:POKEI,J:NEXT:PRINT"[147]"
3009 DATA0,0,126,126,126,126,0,0
3010 POKE1,PEEK(1)OR4:POKE56334,PEEK(56334)OR1:POKE53272,PEEK(53272)AND240OR12
3011 FORC=1024TO1063:POKEC+54272,2:POKEC,35:POKEC+55232,2:POKEC+960,35:NEXT
3012 FORC=1024TO1984STEP40:POKEC+54272,2:POKEC,35:POKEC+54311,2:POKEC+39,35
3013 NEXT
3111 GOTO1
4000 FORL2=1TO5:POKEVL,9:POKECL+5,72:POKECL+6,241:FORL1=50TO25STEP-1
4001 POKECL+1,L1:POKECL+4,33:NEXTL1:NEXTL2:POKECL+4,32
4003 PRINT" UN GARDIEN VOUS A ATTRAPE."
4004 PRINTTAB(17)"[158] OR=[154]"SC
4005 PRINT"[159]PRESSER LE BOUTON FEU SI TU VEUX REJOUER"
4006 PRINT"[159] PRESSER (F) POUR TERMINER"
4007 GETA$:X1=PEEK(56320)AND16:IF A$="F"THENPOKE53272,21:PRINT"[147]":END
4009 IF X1<>0THEN4007
4010 IF SC<>PHTHENPH=SC
4011 PRINT"[147]":SC=0:GOTO3011
5000 PRINT"TU T'ES APPROPRIE DU TRESOR"
5001 POKEVL,15:POKECL+5,71:POKECL+6,241:FORZ=1TO100:POKECL+4,33
5002 POKECL+1,INT(RND(1)*128)+64:FORHG=1TO10:NEXT:NEXT:POKECL+4,32
5100 PRINT"[147]":PRINTTAB(14)" OR=[158]"SC;:PRINT" "
5101 FORL=1TOTR:SC=SC+1:PRINTTAB(21)"[145]"SC:NEXT
5120 PRINT" PRESQUE TOUT LE TRESOR A ETE RETIRE DE LA TOMBE"
5121 PRINT"PLUS GROS TRESOR TROUVE [158]"PH
5122 PRINT"[156] PRESSER F POUR QUITTER MAINTENANT"
5123 PRINT" PRESSER LE BOUTON FEU POUR CONTINUER"
5124 GETA$:X1=PEEK(56320)AND16:IFX1=0THENPRINT"[147]":GOTO3011
5125 IF A$="F"THEN POKE53272,21:PRINT"[147]":END
5126 GOTO5124